.include "m8def.inc"



.def temp = R16



        ldi R16, RAMEND

        out SPL, R16                      ; Stackpointer initialisieren



        ldi R16, (1<<RXEN)|(1<<TXEN)

        out UCSRB, R16

        ldi R17, high(4000000/(9600*16)-1)      ; Baudrate 9600 einstellen

        ldi R16, low(4000000/(9600*16)-1)

        out UBRRH, r17

        out UBRRL, r16

        ldi R16, (1<<URSEL)|(1<<USBS)|(3<<UCSZ0)

        out UCSRC, r16



start:

        ldi ZL, LOW(text*2)               ; Adresse des Strings in den

        ldi ZH, HIGH(text*2)              ; Z-Pointer laden

        rcall print                       ; Unterfunktion print aufrufen



        ldi R16, 10                       ; die Bytes 10 und 13 senden

        rcall sendbyte                    ; (Zeilenumbruch im Terminal)

        ldi R16, 13

        rcall sendbyte

loop:

        rjmp loop                        ; endlosschleife





; print: sendet die durch den Z-Pointer adressierte Zeichenkette

print:

        lpm                               ; Erstes Byte des Strings nach R0 lesen

        tst R0                            ; R0 auf 0 testen

        breq print_end                    ; wenn 0, dann zu print_end

        mov r16, r0                       ; Inhalt von R0 nach R16 kopieren

        rcall sendbyte                    ; UART-Sendefunktion aufrufen

        adiw ZL, 1                        ; Adresse des Z-Pointers um 1 erhöhen

        rjmp print                        ; wieder zum Anfang springen

print_end:

        ret



; sendbyte: sendet das Byte aus R16 über das UART

sendbyte:

        sbis UCSRA, UDRE                  ; warten bis das UART bereit ist

        rjmp sendbyte

        out UDR, R16

        ret



text:

.db "AVR-Assembler ist ganz einfach",13,10,12,0   ; Stringkonstante, durch eine 0 abgeschlossen