unbekanntes Programm entdeckt

Das öffnen der Datei geht nicht, also hier das Listing:

MC68HC711E9 Bootloader ROM
1 ****************************************************
2 * BOOTLOADER FIRMWARE FOR 68HC711E9 - 21 Aug 89
3 ****************************************************
4 * Features of this bootloader are...
5 *
6 * Auto baud select between 7812.5 and 1200 (8 MHz)
7 * 0 - 512 byte variable length download
8 * Jump to EEPROM at $B600 if 1st download byte = $00
9 * PROGRAM - Utility subroutine to program EPROM
10 * UPLOAD - Utility subroutine to dump memory to host
11 * Mask I.D. at $BFD4 = $71E9
12 ****************************************************
13 * Revision A -
14 *
15 * Fixed bug in PROGRAM routine where the first byte
16 * programmed into the EPROM was not transmitted for
17 * verify.
18 * Also added to PROGRAM routine a skip of bytes
19 * which were already programmed to the value desired.
20 *
21 * This new version allows variable length download
22 * by quitting reception of characters when an idle
23 * of at least four character times occurs
24 *
25 ****************************************************
26
27 * EQUATES FOR USE WITH INDEX OFFSET = $1000
28 *
29 0008 PORTD EQU $08
30 000E TCNT EQU $0E
31 0016 TOC1 EQU $16
32 0023 TFLG1 EQU $23
33 * BIT EQUATES FOR TFLG1
34 0080 OC1F EQU $80
35 *
36 0028 SPCR EQU $28 (FOR DWOM BIT)
37 002B BAUD EQU $2B
38 002D SCCR2 EQU $2D
39 002E SCSR EQU $2E
40 002F SCDAT EQU $2F
41 003B PPROG EQU $3B
42 * BIT EQUATES FOR PPROG
43 0020 ELAT EQU $20
44 0001 EPGM EQU $01
45 *
46
Application Note
AN1060 — Rev. 1.0
318 MOTOROLA
47 * MEMORY CONFIGURATION EQUATES
48 *
49 B600 EEPMSTR EQU $B600 Start of EEPROM
50 B7FF EEPMEND EQU $B7FF End of EEPROM
51 *
52 D000 EPRMSTR EQU $D000 Start of EPROM
53 FFFF EPRMEND EQU $FFFF End of EPROM
54 *
55 0000 RAMSTR EQU $0000
56 01FF RAMEND EQU $01FF
57
58 * DELAY CONSTANTS
59 *
60 0DB0 DELAYS EQU 3504 Delay at slow baud
61 021B DELAYF EQU 539 Delay at fast baud
62 *
63 1068 PROGDEL EQU 4200 2 ms programming delay
64 * At 2.1 MHz
65
66 ****************************************************
67 BF00 ORG $BF00
68 ****************************************************
69
70 * Next two instructions provide a predictable place
71 * to call PROGRAM and UPLOAD even if the routines
72 * change size in future versions.
73 *
74 BF00 7EBF13 PROGRAM JMP PRGROUT EPROM programming utility
75 BF03 UPLOAD EQU * Upload utility
76
77 ****************************************************
78 * UPLOAD - Utility subroutine to send data from
79 * inside the MCU to the host via the SCI interface.
80 * Prior to calling UPLOAD set baud rate, turn on SCI
81 * and set Y=first address to upload.
82 * Bootloader leaves baud set, SCI enabled, and
83 * Y pointing at EPROM start ($D000) so these default
84 * values do not have to be changed typically.
85 * Consecutive locations are sent via SCI in an
86 * infinite loop. Reset stops the upload process.
87 ****************************************************
88 BF03 CE1000 LDX #$1000 Point to internal registers
89 BF06 18A600 UPLOOP LDAA 0,Y Read byte
90 BF09 1F2E80FC BRCLR SCSR,X $80 * Wait for TDRE
91 BF0D A72F STAA SCDAT,X Send it
92 BF0F 1808 INY
93 BF11 20F3 BRA UPLOOP Next...
94
Application Note
AN1060 — Rev. 1.0
MOTOROLA 319
95 ****************************************************
96 * PROGRAM - Utility subroutine to program EPROM.
97 * Prior to calling PROGRAM set baud rate, turn on SCI
98 * set X=2ms prog delay constant, and set Y=first
99 * address to program. SP must point to RAM.
100 * Bootloader leaves baud set, SCI enabled, X=4200
101 * and Y pointing at EPROM start ($D000) so these
102 * default values don’t have to be changed typically.
103 * Delay constant in X should be equivalent to 2 ms
104 * at 2.1 MHz X=4200; at 1 MHz X=2000.
105 * An external voltage source is required for EPROM
106 * programming.
107 * This routine uses 2 bytes of stack space
108 * Routine does not return. Reset to exit.
109 ****************************************************
110 BF13 PRGROUT EQU *
111 BF13 3C PSHX Save program delay constant
112 BF14 CE1000 LDX #$1000 Point to internal registers
113 BF17
114 * Send $FF to indicate ready for program data
115
116 BF17 1F2E80FC BRCLR SCSR,X $80 * Wait for TDRE
117 BF1B 86FF LDAA #$FF
118 BF1D A72F STAA SCDAT,X
119
120 BF1F WAIT1 EQU *
121 BF1F 1F2E20FC BRCLR SCSR,X $20 * Wait for RDRF
122 BF23 E62F LDAB SCDAT,X Get received byte
123 BF25 18E100 CMPB $0,Y See if already programmed
124 BF28 271D BEQ DONEIT If so, skip prog cycle
125 BF2A 8620 LDAA #ELAT Put EPROM in prog mode
126 BF2C A73B STAA PPROG,X
127 BF2E 18E700 STAB 0,Y Write the data
128 BF31 8621 LDAA #ELAT+EPGM
129 BF33 A73B STAA PPROG,X Turn on prog voltage
130 BF35 32 PULA Pull delay constant
131 BF36 33 PULB into D-reg
132 BF37 37 PSHB But also keep delay
133 BF38 36 PSHA keep delay on stack
134 BF39 E30E ADDD TCNT,X Delay const + present TCNT
135 BF3B ED16 STD TOC1,X Schedule OC1 (2ms delay)
136 BF3D 8680 LDAA #OC1F
137 BF3F A723 STAA TFLG1,X Clear any previous flag
138
139 BF41 1F2380FC BRCLR TFLG1,X OC1F * Wait for delay to expire
140 BF45 6F3B CLR PPROG,X Turn off prog voltage
141 *
142 BF47 DONEIT EQU *
143 BF47 1F2E80FC BRCLR SCSR,X $80 * Wait for TDRE
144 BF4B 18A600 LDAA $0,Y Read from EPROM and...
145 BF4E A72F STAA SCDAT,X Xmit for verify
146 BF50 1808 INY Point at next location
147 BF52 20CB BRA WAIT1 Back to top for next
148 * Loops indefinitely as long as more data sent.
149
Application Note
AN1060 — Rev. 1.0
320 MOTOROLA
150 ****************************************************
151 * Main bootloader starts here
152 ****************************************************
153 * RESET vector points to here
154
155 BF54 BEGIN EQU *
156 BF54 8E01FF LDS #RAMEND Initialize stack pntr
157 BF57 CE1000 LDX #$1000 Point at internal regs
158 BF5A 1C2820 BSET SPCR,X $20 Select port D wire-OR mode
159 BF5D CCA20C LDD #$A20C BAUD in A, SCCR2 in B
160 BF60 A72B STAA BAUD,X SCPx = ÷4, SCRx = ÷4
161 * Writing 1 to MSB of BAUD resets count chain
162 BF62 E72D STAB SCCR2,X Rx and Tx Enabled
163 BF64 CC021B LDD #DELAYF Delay for fast baud rate
164 BF67 ED16 STD TOC1,X Set as default delay
165
166 * Send BREAK to signal ready for download
167 BF69 1C2D01 BSET SCCR2,X $01 Set send break bit
168 BF6C 1E0801FC BRSET PORTD,X $01 * Wait for RxD pin to go low
169 BF70 1D2D01 BCLR SCCR2,X $01 Clear send break bit
170 BF73
171 BF73 1F2E20FC BRCLR SCSR,X $20 * Wait for RDRF
172 BF77 A62F LDAA SCDAT,X Read data
173 * Data will be $00 if BREAK OR $00 received
174 BF79 2603 BNE NOTZERO Bypass JMP if not 0
175 BF7B 7EB600 JMP EEPMSTR Jump to EEPROM if it was 0
176 BF7E NOTZERO EQU *
177 BF7E 81FF CMPA #$FF $FF will be seen as $FF
178 BF80 2708 BEQ BAUDOK If baud was correct
179 * Or else change to ÷104 (÷13 & ÷8) 1200 @ 2MHZ
180 BF82 1C2B33 BSET BAUD,X $33 Works because $22 -> $33
181 BF85 CC0DB0 LDD #DELAYS And switch to slower...
182 BF88 ED16 STD TOC1,X delay constant
183 BF8A BAUDOK EQU *
184 BF8A 18CE0000 LDY #RAMSTR Point at start of RAM
185
186 BF8E WAIT EQU *
187 BF8E EC16 LDD TOC1,X Move delay constant to D
188 BF90 WTLOOP EQU *
189 BF90 1E2E2007 BRSET SCSR,X $20 NEWONE Exit loop if RDRF set
190 BF94 8F XGDX Swap delay count to X
191 BF95 09 DEX Decrement count
192 BF96 8F XGDX Swap back to D
193 BF97 26F7 BNE WTLOOP Loop if not timed out
194 BF99 200F BRA STAR Quit download on timeout
195
196 BF9B NEWONE EQU *
197 BF9B A62F LDAA SCDAT,X Get received data
198 BF9D 18A700 STAA $00,Y Store to next RAM location
199 BFA0 A72F STAA SCDAT,X Transmit it for handshake
200 BFA2 1808 INY Point at next RAM location
201 BFA4 188C0200 CPY #RAMEND+1 See if past end
202 BFA8 26E4 BNE WAIT If not, Get another
Application Note
AN1060 — Rev. 1.0
MOTOROLA 321
203
204 BFAA STAR EQU *
205 BFAA CE1068 LDX #PROGDEL Init X with programming delay
206 BFAD 18CED000 LDY #EPRMSTR Init Y with EPROM start addr
207 BFB1 7E0000 JMP RAMSTR ** EXIT to start of RAM **
208 BFB4
209 ****************************************************
210 * Block fill unused bytes with zeros
211
212 BFB4 000000000000 BSZ $BFD1-*
000000000000
000000000000
000000000000
0000000000
213
214 ****************************************************
215 * Boot ROM revision level in ASCII
216 * (ORG $BFD1)
217 BFD1 41 FCC "A"
218 ****************************************************
219 * Mask set I.D. ($0000 FOR EPROM PARTS)
220 * (ORG $BFD2)
221 BFD2 0000 FDB $0000
222 ****************************************************
223 * ’711E9 I.D. - Can be used to determine MCU type
224 * (ORG $BFD4)
225 BFD4 71E9 FDB $71E9
226
227 ****************************************************
228 * VECTORS - point to RAM for pseudo-vector JUMPs
229
230 BFD6 00C4 FDB $100-60 SCI
231 BFD8 00C7 FDB $100-57 SPI
232 BFDA 00CA FDB $100-54 PULSE ACCUM INPUT EDGE
233 BFDC 00CD FDB $100-51 PULSE ACCUM OVERFLOW
234 BFDE 00D0 FDB $100-48 TIMER OVERFLOW
235 BFE0 00D3 FDB $100-45 TIMER OUTPUT COMPARE 5
236 BFE2 00D6 FDB $100-42 TIMER OUTPUT COMPARE 4
237 BFE4 00D9 FDB $100-39 TIMER OUTPUT COMPARE 3
238 BFE6 00DC FDB $100-36 TIMER OUTPUT COMPARE 2
239 BFE8 00DF FDB $100-33 TIMER OUTPUT COMPARE 1
240 BFEA 00E2 FDB $100-30 TIMER INPUT CAPTURE 3
241 BFEC 00E5 FDB $100-27 TIMER INPUT CAPTURE 2
242 BFEE 00E8 FDB $100-24 TIMER INPUT CAPTURE 1
243 BFF0 00EB FDB $100-21 REAL TIME INT
244 BFF2 00EE FDB $100-18 IRQ
245 BFF4 00F1 FDB $100-15 XIRQ
246 BFF6 00F4 FDB $100-12 SWI
247 BFF8 00F7 FDB $100-9 ILLEGAL OP-CODE
248 BFFA 00FA FDB $100-6 COP FAIL
249 BFFC 00FD FDB $100-3 CLOCK MONITOR
250 BFFE BF54 FDB BEGIN RESET
251 C000 END

_________________
Es ist nicht mein Ziel mit dem Kopf durch die Wand zu gehen, sondern mit den Augen eine Tür zu finden. Also warum kompliziert, wenn’s einfach geht.